e213ef310f
* Fix minor FD leak in journal code. Closes: #754608 * direct: Fix handling of case where a work tree subdirectory cannot be written to due to permissions. * migrate: Avoid re-checksumming when migrating from hashE to hash backend. * uninit: Avoid failing final removal in some direct mode repositories due to file modes. * S3: Deal with AWS ACL configurations that do not allow creating or checking the location of a bucket, but only reading and writing content to it. * resolvemerge: New plumbing command that runs the automatic merge conflict resolver. * Deal with change in git 2.0 that made indirect mode merge conflict resolution leave behind old files. * sync: Fix git sync with local git remotes even when they don't have an annex.uuid set. (The assistant already did so.) * Set gcrypt-publish-participants when setting up a gcrypt repository, to avoid unncessary passphrase prompts. This is a security/usability tradeoff. To avoid exposing the gpg key ids who can decrypt the repository, users can unset gcrypt-publish-participants. * Install nautilus hooks even when ~/.local/share/nautilus/ does not yet exist, since it is not automatically created for Gnome 3 users. * Windows: Move .vbs files out of git\bin, to avoid that being in the PATH, which caused some weird breakage. (Thanks, divB) * Windows: Fix locking issue that prevented the webapp starting (since 5.20140707). # imported from the archive
69 lines
1.9 KiB
Haskell
69 lines
1.9 KiB
Haskell
{- monadic stuff
|
|
-
|
|
- Copyright 2010-2012 Joey Hess <joey@kitenet.net>
|
|
-
|
|
- License: BSD-2-clause
|
|
-}
|
|
|
|
module Utility.Monad where
|
|
|
|
import Data.Maybe
|
|
import Control.Monad
|
|
|
|
{- Return the first value from a list, if any, satisfying the given
|
|
- predicate -}
|
|
firstM :: Monad m => (a -> m Bool) -> [a] -> m (Maybe a)
|
|
firstM _ [] = return Nothing
|
|
firstM p (x:xs) = ifM (p x) (return $ Just x , firstM p xs)
|
|
|
|
{- Runs the action on values from the list until it succeeds, returning
|
|
- its result. -}
|
|
getM :: Monad m => (a -> m (Maybe b)) -> [a] -> m (Maybe b)
|
|
getM _ [] = return Nothing
|
|
getM p (x:xs) = maybe (getM p xs) (return . Just) =<< p x
|
|
|
|
{- Returns true if any value in the list satisfies the predicate,
|
|
- stopping once one is found. -}
|
|
anyM :: Monad m => (a -> m Bool) -> [a] -> m Bool
|
|
anyM p = liftM isJust . firstM p
|
|
|
|
allM :: Monad m => (a -> m Bool) -> [a] -> m Bool
|
|
allM _ [] = return True
|
|
allM p (x:xs) = p x <&&> allM p xs
|
|
|
|
{- Runs an action on values from a list until it succeeds. -}
|
|
untilTrue :: Monad m => [a] -> (a -> m Bool) -> m Bool
|
|
untilTrue = flip anyM
|
|
|
|
{- if with a monadic conditional. -}
|
|
ifM :: Monad m => m Bool -> (m a, m a) -> m a
|
|
ifM cond (thenclause, elseclause) = do
|
|
c <- cond
|
|
if c then thenclause else elseclause
|
|
|
|
{- short-circuiting monadic || -}
|
|
(<||>) :: Monad m => m Bool -> m Bool -> m Bool
|
|
ma <||> mb = ifM ma ( return True , mb )
|
|
|
|
{- short-circuiting monadic && -}
|
|
(<&&>) :: Monad m => m Bool -> m Bool -> m Bool
|
|
ma <&&> mb = ifM ma ( mb , return False )
|
|
|
|
{- Same fixity as && and || -}
|
|
infixr 3 <&&>
|
|
infixr 2 <||>
|
|
|
|
{- Runs an action, passing its value to an observer before returning it. -}
|
|
observe :: Monad m => (a -> m b) -> m a -> m a
|
|
observe observer a = do
|
|
r <- a
|
|
_ <- observer r
|
|
return r
|
|
|
|
{- b `after` a runs first a, then b, and returns the value of a -}
|
|
after :: Monad m => m b -> m a -> m a
|
|
after = observe . const
|
|
|
|
{- do nothing -}
|
|
noop :: Monad m => m ()
|
|
noop = return ()
|