e213ef310f
* Fix minor FD leak in journal code. Closes: #754608 * direct: Fix handling of case where a work tree subdirectory cannot be written to due to permissions. * migrate: Avoid re-checksumming when migrating from hashE to hash backend. * uninit: Avoid failing final removal in some direct mode repositories due to file modes. * S3: Deal with AWS ACL configurations that do not allow creating or checking the location of a bucket, but only reading and writing content to it. * resolvemerge: New plumbing command that runs the automatic merge conflict resolver. * Deal with change in git 2.0 that made indirect mode merge conflict resolution leave behind old files. * sync: Fix git sync with local git remotes even when they don't have an annex.uuid set. (The assistant already did so.) * Set gcrypt-publish-participants when setting up a gcrypt repository, to avoid unncessary passphrase prompts. This is a security/usability tradeoff. To avoid exposing the gpg key ids who can decrypt the repository, users can unset gcrypt-publish-participants. * Install nautilus hooks even when ~/.local/share/nautilus/ does not yet exist, since it is not automatically created for Gnome 3 users. * Windows: Move .vbs files out of git\bin, to avoid that being in the PATH, which caused some weird breakage. (Thanks, divB) * Windows: Fix locking issue that prevented the webapp starting (since 5.20140707). # imported from the archive
59 lines
1.8 KiB
Haskell
59 lines
1.8 KiB
Haskell
{- Simple IO exception handling (and some more)
|
|
-
|
|
- Copyright 2011-2012 Joey Hess <joey@kitenet.net>
|
|
-
|
|
- License: BSD-2-clause
|
|
-}
|
|
|
|
{-# LANGUAGE ScopedTypeVariables #-}
|
|
|
|
module Utility.Exception where
|
|
|
|
import Control.Exception
|
|
import qualified Control.Exception as E
|
|
import Control.Applicative
|
|
import Control.Monad
|
|
import System.IO.Error (isDoesNotExistError)
|
|
import Utility.Data
|
|
|
|
{- Catches IO errors and returns a Bool -}
|
|
catchBoolIO :: IO Bool -> IO Bool
|
|
catchBoolIO = catchDefaultIO False
|
|
|
|
{- Catches IO errors and returns a Maybe -}
|
|
catchMaybeIO :: IO a -> IO (Maybe a)
|
|
catchMaybeIO a = catchDefaultIO Nothing $ Just <$> a
|
|
|
|
{- Catches IO errors and returns a default value. -}
|
|
catchDefaultIO :: a -> IO a -> IO a
|
|
catchDefaultIO def a = catchIO a (const $ return def)
|
|
|
|
{- Catches IO errors and returns the error message. -}
|
|
catchMsgIO :: IO a -> IO (Either String a)
|
|
catchMsgIO a = either (Left . show) Right <$> tryIO a
|
|
|
|
{- catch specialized for IO errors only -}
|
|
catchIO :: IO a -> (IOException -> IO a) -> IO a
|
|
catchIO = E.catch
|
|
|
|
{- try specialized for IO errors only -}
|
|
tryIO :: IO a -> IO (Either IOException a)
|
|
tryIO = try
|
|
|
|
{- Catches all exceptions except for async exceptions.
|
|
- This is often better to use than catching them all, so that
|
|
- ThreadKilled and UserInterrupt get through.
|
|
-}
|
|
catchNonAsync :: IO a -> (SomeException -> IO a) -> IO a
|
|
catchNonAsync a onerr = a `catches`
|
|
[ Handler (\ (e :: AsyncException) -> throw e)
|
|
, Handler (\ (e :: SomeException) -> onerr e)
|
|
]
|
|
|
|
tryNonAsync :: IO a -> IO (Either SomeException a)
|
|
tryNonAsync a = (Right <$> a) `catchNonAsync` (return . Left)
|
|
|
|
{- Catches only DoesNotExist exceptions, and lets all others through. -}
|
|
tryWhenExists :: IO a -> IO (Maybe a)
|
|
tryWhenExists a = eitherToMaybe <$>
|
|
tryJust (guard . isDoesNotExistError) a
|