e213ef310f
* Fix minor FD leak in journal code. Closes: #754608 * direct: Fix handling of case where a work tree subdirectory cannot be written to due to permissions. * migrate: Avoid re-checksumming when migrating from hashE to hash backend. * uninit: Avoid failing final removal in some direct mode repositories due to file modes. * S3: Deal with AWS ACL configurations that do not allow creating or checking the location of a bucket, but only reading and writing content to it. * resolvemerge: New plumbing command that runs the automatic merge conflict resolver. * Deal with change in git 2.0 that made indirect mode merge conflict resolution leave behind old files. * sync: Fix git sync with local git remotes even when they don't have an annex.uuid set. (The assistant already did so.) * Set gcrypt-publish-participants when setting up a gcrypt repository, to avoid unncessary passphrase prompts. This is a security/usability tradeoff. To avoid exposing the gpg key ids who can decrypt the repository, users can unset gcrypt-publish-participants. * Install nautilus hooks even when ~/.local/share/nautilus/ does not yet exist, since it is not automatically created for Gnome 3 users. * Windows: Move .vbs files out of git\bin, to avoid that being in the PATH, which caused some weird breakage. (Thanks, divB) * Windows: Fix locking issue that prevented the webapp starting (since 5.20140707). # imported from the archive
71 lines
1.7 KiB
Haskell
71 lines
1.7 KiB
Haskell
{- git repository urls
|
|
-
|
|
- Copyright 2010, 2011 Joey Hess <joey@kitenet.net>
|
|
-
|
|
- Licensed under the GNU GPL version 3 or higher.
|
|
-}
|
|
|
|
module Git.Url (
|
|
scheme,
|
|
host,
|
|
port,
|
|
hostuser,
|
|
authority,
|
|
) where
|
|
|
|
import Network.URI hiding (scheme, authority)
|
|
|
|
import Common
|
|
import Git.Types
|
|
import Git
|
|
|
|
{- Scheme of an URL repo. -}
|
|
scheme :: Repo -> String
|
|
scheme Repo { location = Url u } = uriScheme u
|
|
scheme repo = notUrl repo
|
|
|
|
{- Work around a bug in the real uriRegName
|
|
- <http://trac.haskell.org/network/ticket/40> -}
|
|
uriRegName' :: URIAuth -> String
|
|
uriRegName' a = fixup $ uriRegName a
|
|
where
|
|
fixup x@('[':rest)
|
|
| rest !! len == ']' = take len rest
|
|
| otherwise = x
|
|
where
|
|
len = length rest - 1
|
|
fixup x = x
|
|
|
|
{- Hostname of an URL repo. -}
|
|
host :: Repo -> Maybe String
|
|
host = authpart uriRegName'
|
|
|
|
{- Port of an URL repo, if it has a nonstandard one. -}
|
|
port :: Repo -> Maybe Integer
|
|
port r =
|
|
case authpart uriPort r of
|
|
Nothing -> Nothing
|
|
Just ":" -> Nothing
|
|
Just (':':p) -> readish p
|
|
Just _ -> Nothing
|
|
|
|
{- Hostname of an URL repo, including any username (ie, "user@host") -}
|
|
hostuser :: Repo -> Maybe String
|
|
hostuser r = (++)
|
|
<$> authpart uriUserInfo r
|
|
<*> authpart uriRegName' r
|
|
|
|
{- The full authority portion an URL repo. (ie, "user@host:port") -}
|
|
authority :: Repo -> Maybe String
|
|
authority = authpart assemble
|
|
where
|
|
assemble a = uriUserInfo a ++ uriRegName' a ++ uriPort a
|
|
|
|
{- Applies a function to extract part of the uriAuthority of an URL repo. -}
|
|
authpart :: (URIAuth -> a) -> Repo -> Maybe a
|
|
authpart a Repo { location = Url u } = a <$> uriAuthority u
|
|
authpart _ repo = notUrl repo
|
|
|
|
notUrl :: Repo -> a
|
|
notUrl repo = error $
|
|
"acting on local git repo " ++ repoDescribe repo ++ " not supported"
|