e213ef310f
* Fix minor FD leak in journal code. Closes: #754608 * direct: Fix handling of case where a work tree subdirectory cannot be written to due to permissions. * migrate: Avoid re-checksumming when migrating from hashE to hash backend. * uninit: Avoid failing final removal in some direct mode repositories due to file modes. * S3: Deal with AWS ACL configurations that do not allow creating or checking the location of a bucket, but only reading and writing content to it. * resolvemerge: New plumbing command that runs the automatic merge conflict resolver. * Deal with change in git 2.0 that made indirect mode merge conflict resolution leave behind old files. * sync: Fix git sync with local git remotes even when they don't have an annex.uuid set. (The assistant already did so.) * Set gcrypt-publish-participants when setting up a gcrypt repository, to avoid unncessary passphrase prompts. This is a security/usability tradeoff. To avoid exposing the gpg key ids who can decrypt the repository, users can unset gcrypt-publish-participants. * Install nautilus hooks even when ~/.local/share/nautilus/ does not yet exist, since it is not automatically created for Gnome 3 users. * Windows: Move .vbs files out of git\bin, to avoid that being in the PATH, which caused some weird breakage. (Thanks, divB) * Windows: Fix locking issue that prevented the webapp starting (since 5.20140707). # imported from the archive
78 lines
2.1 KiB
Haskell
78 lines
2.1 KiB
Haskell
{- git FilePath library
|
|
-
|
|
- Different git commands use different types of FilePaths to refer to
|
|
- files in the repository. Some commands use paths relative to the
|
|
- top of the repository even when run in a subdirectory. Adding some
|
|
- types helps keep that straight.
|
|
-
|
|
- Copyright 2012-2013 Joey Hess <joey@kitenet.net>
|
|
-
|
|
- Licensed under the GNU GPL version 3 or higher.
|
|
-}
|
|
|
|
{-# LANGUAGE CPP #-}
|
|
|
|
module Git.FilePath (
|
|
TopFilePath,
|
|
fromTopFilePath,
|
|
getTopFilePath,
|
|
toTopFilePath,
|
|
asTopFilePath,
|
|
InternalGitPath,
|
|
toInternalGitPath,
|
|
fromInternalGitPath,
|
|
absoluteGitPath
|
|
) where
|
|
|
|
import Common
|
|
import Git
|
|
|
|
import qualified System.FilePath.Posix
|
|
|
|
{- A FilePath, relative to the top of the git repository. -}
|
|
newtype TopFilePath = TopFilePath { getTopFilePath :: FilePath }
|
|
deriving (Show)
|
|
|
|
{- Returns an absolute FilePath. -}
|
|
fromTopFilePath :: TopFilePath -> Git.Repo -> FilePath
|
|
fromTopFilePath p repo = absPathFrom (repoPath repo) (getTopFilePath p)
|
|
|
|
{- The input FilePath can be absolute, or relative to the CWD. -}
|
|
toTopFilePath :: FilePath -> Git.Repo -> IO TopFilePath
|
|
toTopFilePath file repo = TopFilePath <$>
|
|
relPathDirToFile (repoPath repo) <$> absPath file
|
|
|
|
{- The input FilePath must already be relative to the top of the git
|
|
- repository -}
|
|
asTopFilePath :: FilePath -> TopFilePath
|
|
asTopFilePath file = TopFilePath file
|
|
|
|
{- Git may use a different representation of a path when storing
|
|
- it internally.
|
|
-
|
|
- On Windows, git uses '/' to separate paths stored in the repository,
|
|
- despite Windows using '\'.
|
|
-
|
|
-}
|
|
type InternalGitPath = String
|
|
|
|
toInternalGitPath :: FilePath -> InternalGitPath
|
|
#ifndef mingw32_HOST_OS
|
|
toInternalGitPath = id
|
|
#else
|
|
toInternalGitPath = replace "\\" "/"
|
|
#endif
|
|
|
|
fromInternalGitPath :: InternalGitPath -> FilePath
|
|
#ifndef mingw32_HOST_OS
|
|
fromInternalGitPath = id
|
|
#else
|
|
fromInternalGitPath = replace "/" "\\"
|
|
#endif
|
|
|
|
{- isAbsolute on Windows does not think "/foo" or "\foo" is absolute,
|
|
- so try posix paths.
|
|
-}
|
|
absoluteGitPath :: FilePath -> Bool
|
|
absoluteGitPath p = isAbsolute p ||
|
|
System.FilePath.Posix.isAbsolute (toInternalGitPath p)
|