e213ef310f
* Fix minor FD leak in journal code. Closes: #754608 * direct: Fix handling of case where a work tree subdirectory cannot be written to due to permissions. * migrate: Avoid re-checksumming when migrating from hashE to hash backend. * uninit: Avoid failing final removal in some direct mode repositories due to file modes. * S3: Deal with AWS ACL configurations that do not allow creating or checking the location of a bucket, but only reading and writing content to it. * resolvemerge: New plumbing command that runs the automatic merge conflict resolver. * Deal with change in git 2.0 that made indirect mode merge conflict resolution leave behind old files. * sync: Fix git sync with local git remotes even when they don't have an annex.uuid set. (The assistant already did so.) * Set gcrypt-publish-participants when setting up a gcrypt repository, to avoid unncessary passphrase prompts. This is a security/usability tradeoff. To avoid exposing the gpg key ids who can decrypt the repository, users can unset gcrypt-publish-participants. * Install nautilus hooks even when ~/.local/share/nautilus/ does not yet exist, since it is not automatically created for Gnome 3 users. * Windows: Move .vbs files out of git\bin, to avoid that being in the PATH, which caused some weird breakage. (Thanks, divB) * Windows: Fix locking issue that prevented the webapp starting (since 5.20140707). # imported from the archive
87 lines
2.5 KiB
Haskell
87 lines
2.5 KiB
Haskell
{- xmpp buddies
|
|
-
|
|
- Copyright 2012 Joey Hess <joey@kitenet.net>
|
|
-
|
|
- Licensed under the GNU GPL version 3 or higher.
|
|
-}
|
|
|
|
module Assistant.XMPP.Buddies where
|
|
|
|
import Assistant.XMPP
|
|
import Common.Annex
|
|
import Assistant.Types.Buddies
|
|
|
|
import Network.Protocol.XMPP
|
|
import qualified Data.Map as M
|
|
import qualified Data.Set as S
|
|
import Data.Text (Text)
|
|
import qualified Data.Text as T
|
|
|
|
genBuddyKey :: JID -> BuddyKey
|
|
genBuddyKey j = BuddyKey $ formatJID $ baseJID j
|
|
|
|
buddyName :: JID -> Text
|
|
buddyName j = maybe (T.pack "") strNode (jidNode j)
|
|
|
|
ucFirst :: Text -> Text
|
|
ucFirst s = let (first, rest) = T.splitAt 1 s
|
|
in T.concat [T.toUpper first, rest]
|
|
|
|
{- Summary of info about a buddy.
|
|
-
|
|
- If the buddy has no clients at all anymore, returns Nothing. -}
|
|
buddySummary :: [JID] -> Buddy -> Maybe (Text, Bool, Bool, Bool, BuddyKey)
|
|
buddySummary pairedwith b = case clients of
|
|
((Client j):_) -> Just (buddyName j, away, canpair, alreadypaired j, genBuddyKey j)
|
|
[] -> Nothing
|
|
where
|
|
away = S.null (buddyPresent b) && S.null (buddyAssistants b)
|
|
canpair = not $ S.null (buddyAssistants b)
|
|
clients = S.toList $ buddyPresent b `S.union` buddyAway b `S.union` buddyAssistants b
|
|
alreadypaired j = baseJID j `elem` pairedwith
|
|
|
|
{- Updates the buddies with XMPP presence info. -}
|
|
updateBuddies :: Presence -> Buddies -> Buddies
|
|
updateBuddies p@(Presence { presenceFrom = Just jid }) = M.alter update key
|
|
where
|
|
key = genBuddyKey jid
|
|
update (Just b) = Just $ applyPresence p b
|
|
update Nothing = newBuddy p
|
|
updateBuddies _ = id
|
|
|
|
{- Creates a new buddy based on XMPP presence info. -}
|
|
newBuddy :: Presence -> Maybe Buddy
|
|
newBuddy p
|
|
| presenceType p == PresenceAvailable = go
|
|
| presenceType p == PresenceUnavailable = go
|
|
| otherwise = Nothing
|
|
where
|
|
go = make <$> presenceFrom p
|
|
make _jid = applyPresence p $ Buddy
|
|
{ buddyPresent = S.empty
|
|
, buddyAway = S.empty
|
|
, buddyAssistants = S.empty
|
|
, buddyPairing = False
|
|
}
|
|
|
|
applyPresence :: Presence -> Buddy -> Buddy
|
|
applyPresence p b = fromMaybe b $! go <$> presenceFrom p
|
|
where
|
|
go jid
|
|
| presenceType p == PresenceUnavailable = b
|
|
{ buddyAway = addto $ buddyAway b
|
|
, buddyPresent = removefrom $ buddyPresent b
|
|
, buddyAssistants = removefrom $ buddyAssistants b
|
|
}
|
|
| hasGitAnnexTag p = b
|
|
{ buddyAssistants = addto $ buddyAssistants b
|
|
, buddyAway = removefrom $ buddyAway b }
|
|
| presenceType p == PresenceAvailable = b
|
|
{ buddyPresent = addto $ buddyPresent b
|
|
, buddyAway = removefrom $ buddyAway b
|
|
}
|
|
| otherwise = b
|
|
where
|
|
client = Client jid
|
|
removefrom = S.filter (/= client)
|
|
addto = S.insert client
|