e213ef310f
* Fix minor FD leak in journal code. Closes: #754608 * direct: Fix handling of case where a work tree subdirectory cannot be written to due to permissions. * migrate: Avoid re-checksumming when migrating from hashE to hash backend. * uninit: Avoid failing final removal in some direct mode repositories due to file modes. * S3: Deal with AWS ACL configurations that do not allow creating or checking the location of a bucket, but only reading and writing content to it. * resolvemerge: New plumbing command that runs the automatic merge conflict resolver. * Deal with change in git 2.0 that made indirect mode merge conflict resolution leave behind old files. * sync: Fix git sync with local git remotes even when they don't have an annex.uuid set. (The assistant already did so.) * Set gcrypt-publish-participants when setting up a gcrypt repository, to avoid unncessary passphrase prompts. This is a security/usability tradeoff. To avoid exposing the gpg key ids who can decrypt the repository, users can unset gcrypt-publish-participants. * Install nautilus hooks even when ~/.local/share/nautilus/ does not yet exist, since it is not automatically created for Gnome 3 users. * Windows: Move .vbs files out of git\bin, to avoid that being in the PATH, which caused some weird breakage. (Thanks, divB) * Windows: Fix locking issue that prevented the webapp starting (since 5.20140707). # imported from the archive
60 lines
2.1 KiB
Haskell
60 lines
2.1 KiB
Haskell
{- git-annex branch transitions
|
|
-
|
|
- Copyright 2013 Joey Hess <joey@kitenet.net>
|
|
-
|
|
- Licensed under the GNU GPL version 3 or higher.
|
|
-}
|
|
|
|
module Annex.Branch.Transitions (
|
|
FileTransition(..),
|
|
getTransitionCalculator
|
|
) where
|
|
|
|
import Logs
|
|
import Logs.Transitions
|
|
import Logs.UUIDBased as UUIDBased
|
|
import Logs.Presence.Pure as Presence
|
|
import Types.TrustLevel
|
|
import Types.UUID
|
|
|
|
import qualified Data.Map as M
|
|
|
|
data FileTransition
|
|
= ChangeFile String
|
|
| RemoveFile
|
|
| PreserveFile
|
|
|
|
type TransitionCalculator = FilePath -> String -> TrustMap -> FileTransition
|
|
|
|
getTransitionCalculator :: Transition -> Maybe TransitionCalculator
|
|
getTransitionCalculator ForgetGitHistory = Nothing
|
|
getTransitionCalculator ForgetDeadRemotes = Just dropDead
|
|
|
|
dropDead :: FilePath -> String -> TrustMap -> FileTransition
|
|
dropDead f content trustmap = case getLogVariety f of
|
|
Just UUIDBasedLog
|
|
-- Don't remove the dead repo from the trust log,
|
|
-- because git remotes may still exist, and they need
|
|
-- to still know it's dead.
|
|
| f == trustLog -> PreserveFile
|
|
| otherwise -> ChangeFile $ UUIDBased.showLog id $ dropDeadFromUUIDBasedLog trustmap $ UUIDBased.parseLog Just content
|
|
Just NewUUIDBasedLog -> ChangeFile $
|
|
UUIDBased.showLogNew id $ dropDeadFromUUIDBasedLog trustmap $ UUIDBased.parseLogNew Just content
|
|
Just (PresenceLog _) ->
|
|
let newlog = Presence.compactLog $ dropDeadFromPresenceLog trustmap $ Presence.parseLog content
|
|
in if null newlog
|
|
then RemoveFile
|
|
else ChangeFile $ Presence.showLog newlog
|
|
Just OtherLog -> PreserveFile
|
|
Nothing -> PreserveFile
|
|
|
|
dropDeadFromUUIDBasedLog :: TrustMap -> UUIDBased.Log String -> UUIDBased.Log String
|
|
dropDeadFromUUIDBasedLog trustmap = M.filterWithKey $ notDead trustmap . const
|
|
|
|
{- Presence logs can contain UUIDs or other values. Any line that matches
|
|
- a dead uuid is dropped; any other values are passed through. -}
|
|
dropDeadFromPresenceLog :: TrustMap -> [Presence.LogLine] -> [Presence.LogLine]
|
|
dropDeadFromPresenceLog trustmap = filter $ notDead trustmap (toUUID . Presence.info)
|
|
|
|
notDead :: TrustMap -> (v -> UUID) -> v -> Bool
|
|
notDead trustmap a v = M.findWithDefault SemiTrusted (a v) trustmap /= DeadTrusted
|