40ecf58d4bThis does not change the overall license of the git-annex program, which was already AGPL due to a number of sources files being AGPL already. Legally speaking, I'm adding a new license under which these files are now available; I already released their current contents under the GPL license. Now they're dual licensed GPL and AGPL. However, I intend for all my future changes to these files to only be released under the AGPL license, and I won't be tracking the dual licensing status, so I'm simply changing the license statement to say it's AGPL. (In some cases, others wrote parts of the code of a file and released it under the GPL; but in all cases I have contributed a significant portion of the code in each file and it's that code that is getting the AGPL license; the GPL license of other contributors allows combining with AGPL code.)
71 lines
2 KiB
Haskell
71 lines
2 KiB
Haskell
{- git-remote-daemon utilities
|
|
-
|
|
- Copyright 2014-2016 Joey Hess <id@joeyh.name>
|
|
-
|
|
- Licensed under the GNU AGPL version 3 or higher.
|
|
-}
|
|
|
|
module RemoteDaemon.Common
|
|
( liftAnnex
|
|
, inLocalRepo
|
|
, checkShouldFetch
|
|
, ConnectionStatus(..)
|
|
, robustConnection
|
|
) where
|
|
|
|
import qualified Annex
|
|
import Annex.Common
|
|
import RemoteDaemon.Types
|
|
import qualified Git
|
|
import Annex.CatFile
|
|
import Utility.ThreadScheduler
|
|
|
|
import Control.Concurrent
|
|
|
|
-- Runs an Annex action. Long-running actions should be avoided,
|
|
-- since only one liftAnnex can be running at a time, across all
|
|
-- transports.
|
|
liftAnnex :: TransportHandle -> Annex a -> IO a
|
|
liftAnnex (TransportHandle _ annexstate) a = do
|
|
st <- takeMVar annexstate
|
|
(r, st') <- Annex.run st a
|
|
putMVar annexstate st'
|
|
return r
|
|
|
|
inLocalRepo :: TransportHandle -> (Git.Repo -> IO a) -> IO a
|
|
inLocalRepo (TransportHandle (LocalRepo g) _) a = a g
|
|
|
|
-- Check if some shas should be fetched from the remote,
|
|
-- and presumably later merged.
|
|
checkShouldFetch :: RemoteGitConfig -> TransportHandle -> [Git.Sha] -> IO Bool
|
|
checkShouldFetch gc transporthandle shas
|
|
| remoteAnnexPull gc = checkNewShas transporthandle shas
|
|
| otherwise = return False
|
|
|
|
-- Check if any of the shas are actally new in the local git repo,
|
|
-- to avoid unnecessary fetching.
|
|
checkNewShas :: TransportHandle -> [Git.Sha] -> IO Bool
|
|
checkNewShas transporthandle = check
|
|
where
|
|
check [] = return True
|
|
check (r:rs) = maybe (check rs) (const $ return False)
|
|
=<< liftAnnex transporthandle (catObjectDetails r)
|
|
|
|
data ConnectionStatus = ConnectionStopping | ConnectionClosed
|
|
|
|
{- Make connection robust, retrying on error, with exponential backoff. -}
|
|
robustConnection :: Int -> IO ConnectionStatus -> IO ()
|
|
robustConnection backoff a =
|
|
caught =<< a `catchNonAsync` (const $ return ConnectionClosed)
|
|
where
|
|
caught ConnectionStopping = return ()
|
|
caught ConnectionClosed = do
|
|
threadDelaySeconds (Seconds backoff)
|
|
robustConnection increasedbackoff a
|
|
|
|
increasedbackoff
|
|
| b2 > maxbackoff = maxbackoff
|
|
| otherwise = b2
|
|
where
|
|
b2 = backoff * 2
|
|
maxbackoff = 3600 -- one hour
|