3a05d53761
No behavior changes (hopefully), just adding SeekInput and plumbing it through to the JSON display code for later use. Over the course of 2 grueling days. withFilesNotInGit reimplemented in terms of seekHelper should be the only possible behavior change. It seems to test as behaving the same. Note that seekHelper dummies up the SeekInput in the case where segmentPaths' gives up on sorting the expanded paths because there are too many input paths. When SeekInput later gets exposed as a json field, that will result in it being a little bit wrong in the case where 100 or more paths are passed to a git-annex command. I think this is a subtle enough problem to not matter. If it does turn out to be a problem, fixing it would require splitting up the input parameters into groups of < 100, which would make git ls-files run perhaps more than is necessary. May want to revisit this, because that fix seems fairly low-impact.
39 lines
1.1 KiB
Haskell
39 lines
1.1 KiB
Haskell
{- git-annex command
|
||
-
|
||
- Copyright 2013 Joey Hess <id@joeyh.name>
|
||
-
|
||
- Licensed under the GNU AGPL version 3 or higher.
|
||
-}
|
||
|
||
module Command.GCryptSetup where
|
||
|
||
import Command
|
||
import Annex.UUID
|
||
import qualified Remote.GCrypt
|
||
import qualified Git
|
||
|
||
cmd :: Command
|
||
cmd = dontCheck repoExists $ noCommit $
|
||
command "gcryptsetup" SectionPlumbing
|
||
"sets up gcrypt repository"
|
||
paramValue (withParams seek)
|
||
|
||
seek :: CmdParams -> CommandSeek
|
||
seek = withStrings (commandAction . start)
|
||
|
||
start :: String -> CommandStart
|
||
start gcryptid = starting "gcryptsetup" (ActionItemOther Nothing) (SeekInput [gcryptid]) $ do
|
||
u <- getUUID
|
||
when (u /= NoUUID) $
|
||
giveup "gcryptsetup refusing to run; this repository already has a git-annex uuid!"
|
||
|
||
g <- gitRepo
|
||
gu <- Remote.GCrypt.getGCryptUUID True g
|
||
let newgu = genUUIDInNameSpace gCryptNameSpace gcryptid
|
||
if isNothing gu || gu == Just newgu
|
||
then if Git.repoIsLocalBare g
|
||
then do
|
||
void $ Remote.GCrypt.setupRepo gcryptid g
|
||
next $ return True
|
||
else giveup "cannot use gcrypt in a non-bare repository"
|
||
else giveup "gcryptsetup uuid mismatch"
|