34c8af74ba
I've been disliking how the command seek actions were written for some time, with their inversion of control and ugly workarounds. The last straw to fix it was sync --content, which didn't fit the Annex [CommandStart] interface well at all. I have not yet made it take advantage of the changed interface though. The crucial change, and probably why I didn't do it this way from the beginning, is to make each CommandStart action be run with exceptions caught, and if it fails, increment a failure counter in annex state. So I finally remove the very first code I wrote for git-annex, which was before I had exception handling in the Annex monad, and so ran outside that monad, passing state explicitly as it ran each CommandStart action. This was a real slog from 1 to 5 am. Test suite passes. Memory usage is lower than before, sometimes by a couple of megabytes, and remains constant, even when running in a large repo, and even when repeatedly failing and incrementing the error counter. So no accidental laziness space leaks. Wall clock speed is identical, even in large repos. This commit was sponsored by an anonymous bitcoiner.
118 lines
3.4 KiB
Haskell
118 lines
3.4 KiB
Haskell
{- git-annex command
|
|
-
|
|
- Copyright 2012-2013 Joey Hess <joey@kitenet.net>
|
|
-
|
|
- Licensed under the GNU GPL version 3 or higher.
|
|
-}
|
|
|
|
module Command.Import where
|
|
|
|
import System.PosixCompat.Files
|
|
|
|
import Common.Annex
|
|
import Command
|
|
import qualified Annex
|
|
import qualified Command.Add
|
|
import qualified Option
|
|
import Utility.CopyFile
|
|
import Backend
|
|
import Remote
|
|
import Types.KeySource
|
|
|
|
def :: [Command]
|
|
def = [withOptions opts $ notBareRepo $ command "import" paramPaths seek
|
|
SectionCommon "move and add files from outside git working copy"]
|
|
|
|
opts :: [Option]
|
|
opts =
|
|
[ duplicateOption
|
|
, deduplicateOption
|
|
, cleanDuplicatesOption
|
|
, skipDuplicatesOption
|
|
]
|
|
|
|
duplicateOption :: Option
|
|
duplicateOption = Option.flag [] "duplicate" "do not delete source files"
|
|
|
|
deduplicateOption :: Option
|
|
deduplicateOption = Option.flag [] "deduplicate" "delete source files whose content was imported before"
|
|
|
|
cleanDuplicatesOption :: Option
|
|
cleanDuplicatesOption = Option.flag [] "clean-duplicates" "delete duplicate source files (import nothing)"
|
|
|
|
skipDuplicatesOption :: Option
|
|
skipDuplicatesOption = Option.flag [] "skip-duplicates" "import only new files"
|
|
|
|
data DuplicateMode = Default | Duplicate | DeDuplicate | CleanDuplicates | SkipDuplicates
|
|
deriving (Eq)
|
|
|
|
getDuplicateMode :: Annex DuplicateMode
|
|
getDuplicateMode = gen
|
|
<$> getflag duplicateOption
|
|
<*> getflag deduplicateOption
|
|
<*> getflag cleanDuplicatesOption
|
|
<*> getflag skipDuplicatesOption
|
|
where
|
|
getflag = Annex.getFlag . Option.name
|
|
gen False False False False = Default
|
|
gen True False False False = Duplicate
|
|
gen False True False False = DeDuplicate
|
|
gen False False True False = CleanDuplicates
|
|
gen False False False True = SkipDuplicates
|
|
gen _ _ _ _ = error "bad combination of --duplicate, --deduplicate, --clean-duplicates, --skip-duplicates"
|
|
|
|
seek :: CommandSeek
|
|
seek ps = do
|
|
mode <- getDuplicateMode
|
|
withPathContents (start mode) ps
|
|
|
|
start :: DuplicateMode -> (FilePath, FilePath) -> CommandStart
|
|
start mode (srcfile, destfile) =
|
|
ifM (liftIO $ isRegularFile <$> getSymbolicLinkStatus srcfile)
|
|
( do
|
|
isdup <- do
|
|
backend <- chooseBackend destfile
|
|
let ks = KeySource srcfile srcfile Nothing
|
|
v <- genKey ks backend
|
|
case v of
|
|
Just (k, _) -> not . null <$> keyLocations k
|
|
_ -> return False
|
|
case pickaction isdup of
|
|
Nothing -> stop
|
|
Just a -> do
|
|
showStart "import" destfile
|
|
next a
|
|
, stop
|
|
)
|
|
where
|
|
deletedup = do
|
|
showNote "duplicate"
|
|
liftIO $ removeFile srcfile
|
|
next $ return True
|
|
importfile = do
|
|
handleexisting =<< liftIO (catchMaybeIO $ getSymbolicLinkStatus destfile)
|
|
liftIO $ createDirectoryIfMissing True (parentDir destfile)
|
|
liftIO $ if mode == Duplicate || mode == SkipDuplicates
|
|
then void $ copyFileExternal srcfile destfile
|
|
else moveFile srcfile destfile
|
|
Command.Add.perform destfile
|
|
handleexisting Nothing = noop
|
|
handleexisting (Just s)
|
|
| isDirectory s = notoverwriting "(is a directory)"
|
|
| otherwise = ifM (Annex.getState Annex.force) $
|
|
( liftIO $ nukeFile destfile
|
|
, notoverwriting "(use --force to override)"
|
|
)
|
|
notoverwriting why = error $ "not overwriting existing " ++ destfile ++ " " ++ why
|
|
pickaction isdup = case mode of
|
|
DeDuplicate
|
|
| isdup -> Just deletedup
|
|
| otherwise -> Just importfile
|
|
CleanDuplicates
|
|
| isdup -> Just deletedup
|
|
| otherwise -> Nothing
|
|
SkipDuplicates
|
|
| isdup -> Nothing
|
|
| otherwise -> Just importfile
|
|
_ -> Just importfile
|
|
|