34c8af74ba
I've been disliking how the command seek actions were written for some time, with their inversion of control and ugly workarounds. The last straw to fix it was sync --content, which didn't fit the Annex [CommandStart] interface well at all. I have not yet made it take advantage of the changed interface though. The crucial change, and probably why I didn't do it this way from the beginning, is to make each CommandStart action be run with exceptions caught, and if it fails, increment a failure counter in annex state. So I finally remove the very first code I wrote for git-annex, which was before I had exception handling in the Annex monad, and so ran outside that monad, passing state explicitly as it ran each CommandStart action. This was a real slog from 1 to 5 am. Test suite passes. Memory usage is lower than before, sometimes by a couple of megabytes, and remains constant, even when running in a large repo, and even when repeatedly failing and incrementing the error counter. So no accidental laziness space leaks. Wall clock speed is identical, even in large repos. This commit was sponsored by an anonymous bitcoiner.
74 lines
2.1 KiB
Haskell
74 lines
2.1 KiB
Haskell
{- git-annex command
|
|
-
|
|
- Copyright 2010-2012 Joey Hess <joey@kitenet.net>
|
|
-
|
|
- Licensed under the GNU GPL version 3 or higher.
|
|
-}
|
|
|
|
module Command.Find where
|
|
|
|
import qualified Data.Map as M
|
|
|
|
import Common.Annex
|
|
import Command
|
|
import Annex.Content
|
|
import Limit
|
|
import qualified Annex
|
|
import qualified Utility.Format
|
|
import Utility.DataUnits
|
|
import Types.Key
|
|
import qualified Option
|
|
import GitAnnex.Options
|
|
|
|
def :: [Command]
|
|
def = [noCommit $ noMessages $ withOptions [formatOption, print0Option, jsonOption] $
|
|
command "find" paramPaths seek SectionQuery "lists available files"]
|
|
|
|
formatOption :: Option
|
|
formatOption = Option.field [] "format" paramFormat "control format of output"
|
|
|
|
getFormat :: Annex (Maybe Utility.Format.Format)
|
|
getFormat = getOptionField formatOption $ return . fmap Utility.Format.gen
|
|
|
|
print0Option :: Option
|
|
print0Option = Option.Option [] ["print0"] (Option.NoArg set)
|
|
"terminate output with null"
|
|
where
|
|
set = Annex.setField (Option.name formatOption) "${file}\0"
|
|
|
|
seek :: CommandSeek
|
|
seek ps = do
|
|
format <- getFormat
|
|
withFilesInGit (whenAnnexed $ start format) ps
|
|
|
|
start :: Maybe Utility.Format.Format -> FilePath -> (Key, Backend) -> CommandStart
|
|
start format file (key, _) = do
|
|
-- only files inAnnex are shown, unless the user has requested
|
|
-- others via a limit
|
|
whenM (limited <||> inAnnex key) $
|
|
showFormatted format file $ ("file", file) : keyVars key
|
|
stop
|
|
|
|
showFormatted :: Maybe Utility.Format.Format -> String -> [(String, String)] -> Annex ()
|
|
showFormatted format unformatted vars =
|
|
unlessM (showFullJSON vars) $
|
|
case format of
|
|
Nothing -> liftIO $ putStrLn unformatted
|
|
Just formatter -> liftIO $ putStr $
|
|
Utility.Format.format formatter $
|
|
M.fromList vars
|
|
|
|
keyVars :: Key -> [(String, String)]
|
|
keyVars key =
|
|
[ ("key", key2file key)
|
|
, ("backend", keyBackendName key)
|
|
, ("bytesize", size show)
|
|
, ("humansize", size $ roughSize storageUnits True)
|
|
, ("keyname", keyName key)
|
|
, ("hashdirlower", hashDirLower key)
|
|
, ("hashdirmixed", hashDirMixed key)
|
|
, ("mtime", whenavail show $ keyMtime key)
|
|
]
|
|
where
|
|
size c = whenavail c $ keySize key
|
|
whenavail = maybe "unknown"
|