5a081fc246This is groundwork for a annex.trashbin feature. Annex.Content cannot import Remote.List due to cyclic dependencies, so instead all calls need to pass in an action to get the remote list. In the case of Remote.*, it's also not possible for them to import Remote.List. Using Annex.remotes there on the same grounds as some prior uses; in order for a Remote to call the code that uses Annex.remotes, the remote list must have already been populated.
60 lines
1.5 KiB
Haskell
60 lines
1.5 KiB
Haskell
{- git-annex command
|
|
-
|
|
- Copyright 2010,2016 Joey Hess <id@joeyh.name>
|
|
-
|
|
- Licensed under the GNU AGPL version 3 or higher.
|
|
-}
|
|
|
|
module Command.DropKey where
|
|
|
|
import Command
|
|
import qualified Annex
|
|
import Logs.Location
|
|
import Annex.Content
|
|
import Remote.List
|
|
|
|
cmd :: Command
|
|
cmd = noCommit $ withAnnexOptions [jsonOptions] $
|
|
command "dropkey" SectionPlumbing
|
|
"drops annexed content for specified keys"
|
|
(paramRepeating paramKey)
|
|
(seek <$$> optParser)
|
|
|
|
data DropKeyOptions = DropKeyOptions
|
|
{ toDrop :: [String]
|
|
, batchOption :: BatchMode
|
|
}
|
|
|
|
optParser :: CmdParamsDesc -> Parser DropKeyOptions
|
|
optParser desc = DropKeyOptions
|
|
<$> cmdParams desc
|
|
<*> parseBatchOption False
|
|
|
|
seek :: DropKeyOptions -> CommandSeek
|
|
seek o = do
|
|
unlessM (Annex.getRead Annex.force) $
|
|
giveup "dropkey can cause data loss; use --force if you're sure you want to do this"
|
|
case batchOption o of
|
|
NoBatch -> withKeys (commandAction . start) (toDrop o)
|
|
Batch fmt -> batchOnly Nothing (toDrop o) $
|
|
batchInput fmt (pure . parsekey) $
|
|
batchCommandAction . start
|
|
where
|
|
parsekey = maybe (Left "bad key") Right . deserializeKey
|
|
|
|
start :: (SeekInput, Key) -> CommandStart
|
|
start (si, key) = starting "dropkey" (mkActionItem key) si $
|
|
perform key
|
|
|
|
perform :: Key -> CommandPerform
|
|
perform key = ifM (inAnnex key)
|
|
( lockContentForRemoval key (next $ cleanup key) $ \contentlock -> do
|
|
removeAnnex remoteList contentlock
|
|
next $ cleanup key
|
|
, next $ return True
|
|
)
|
|
|
|
cleanup :: Key -> CommandCleanup
|
|
cleanup key = do
|
|
logStatus NoLiveUpdate key InfoMissing
|
|
return True
|