eb33569f9d
This removes a bit of complexity, and should make things faster (avoids tokenizing Params string), and probably involve less garbage collection. In a few places, it was useful to use Params to avoid needing a list, but that is easily avoided. Problems noticed while doing this conversion: * Some uses of Params "oneword" which was entirely unnecessary overhead. * A few places that built up a list of parameters with ++ and then used Params to split it! Test suite passes.
77 lines
1.7 KiB
Haskell
77 lines
1.7 KiB
Haskell
{- git ls-tree interface
|
|
-
|
|
- Copyright 2011 Joey Hess <id@joeyh.name>
|
|
-
|
|
- Licensed under the GNU GPL version 3 or higher.
|
|
-}
|
|
|
|
module Git.LsTree (
|
|
TreeItem(..),
|
|
lsTree,
|
|
lsTreeParams,
|
|
lsTreeFiles,
|
|
parseLsTree
|
|
) where
|
|
|
|
import Common
|
|
import Git
|
|
import Git.Command
|
|
import Git.Sha
|
|
import Git.FilePath
|
|
import qualified Git.Filename
|
|
|
|
import Numeric
|
|
import System.Posix.Types
|
|
|
|
data TreeItem = TreeItem
|
|
{ mode :: FileMode
|
|
, typeobj :: String
|
|
, sha :: String
|
|
, file :: TopFilePath
|
|
} deriving Show
|
|
|
|
{- Lists the complete contents of a tree, recursing into sub-trees,
|
|
- with lazy output. -}
|
|
lsTree :: Ref -> Repo -> IO [TreeItem]
|
|
lsTree t repo = map parseLsTree
|
|
<$> pipeNullSplitZombie (lsTreeParams t) repo
|
|
|
|
lsTreeParams :: Ref -> [CommandParam]
|
|
lsTreeParams t =
|
|
[ Param "ls-tree"
|
|
, Param "--full-tree"
|
|
, Param "-z"
|
|
, Param "-r"
|
|
, Param "--"
|
|
, File $ fromRef t
|
|
]
|
|
|
|
{- Lists specified files in a tree. -}
|
|
lsTreeFiles :: Ref -> [FilePath] -> Repo -> IO [TreeItem]
|
|
lsTreeFiles t fs repo = map parseLsTree <$> pipeNullSplitStrict ps repo
|
|
where
|
|
ps =
|
|
[ Param "ls-tree"
|
|
, Param "--full-tree"
|
|
, Param "-z"
|
|
, Param "--"
|
|
, File $ fromRef t
|
|
] ++ map File fs
|
|
|
|
{- Parses a line of ls-tree output.
|
|
- (The --long format is not currently supported.) -}
|
|
parseLsTree :: String -> TreeItem
|
|
parseLsTree l = TreeItem
|
|
{ mode = fst $ Prelude.head $ readOct m
|
|
, typeobj = t
|
|
, sha = s
|
|
, file = asTopFilePath $ Git.Filename.decode f
|
|
}
|
|
where
|
|
-- l = <mode> SP <type> SP <sha> TAB <file>
|
|
-- All fields are fixed, so we can pull them out of
|
|
-- specific positions in the line.
|
|
(m, past_m) = splitAt 7 l
|
|
(t, past_t) = splitAt 4 past_m
|
|
(s, past_s) = splitAt shaSize $ Prelude.tail past_t
|
|
f = Prelude.tail past_s
|