34c8af74ba
I've been disliking how the command seek actions were written for some time, with their inversion of control and ugly workarounds. The last straw to fix it was sync --content, which didn't fit the Annex [CommandStart] interface well at all. I have not yet made it take advantage of the changed interface though. The crucial change, and probably why I didn't do it this way from the beginning, is to make each CommandStart action be run with exceptions caught, and if it fails, increment a failure counter in annex state. So I finally remove the very first code I wrote for git-annex, which was before I had exception handling in the Annex monad, and so ran outside that monad, passing state explicitly as it ran each CommandStart action. This was a real slog from 1 to 5 am. Test suite passes. Memory usage is lower than before, sometimes by a couple of megabytes, and remains constant, even when running in a large repo, and even when repeatedly failing and incrementing the error counter. So no accidental laziness space leaks. Wall clock speed is identical, even in large repos. This commit was sponsored by an anonymous bitcoiner.
98 lines
2.8 KiB
Haskell
98 lines
2.8 KiB
Haskell
{- git-annex command
|
|
-
|
|
- Copyright 2010-2013 Joey Hess <joey@kitenet.net>
|
|
-
|
|
- Licensed under the GNU GPL version 3 or higher.
|
|
-}
|
|
|
|
{-# LANGUAGE CPP #-}
|
|
|
|
module Command.Unannex where
|
|
|
|
import Common.Annex
|
|
import Command
|
|
import Config
|
|
import qualified Annex
|
|
import Annex.Content
|
|
import Annex.Content.Direct
|
|
import qualified Git.Command
|
|
import qualified Git.LsFiles as LsFiles
|
|
import Utility.CopyFile
|
|
|
|
def :: [Command]
|
|
def = [command "unannex" paramPaths seek SectionUtility
|
|
"undo accidential add command"]
|
|
|
|
seek :: CommandSeek
|
|
seek = withFilesInGit $ whenAnnexed start
|
|
|
|
start :: FilePath -> (Key, Backend) -> CommandStart
|
|
start file (key, _) = stopUnless (inAnnex key) $ do
|
|
showStart "unannex" file
|
|
next $ ifM isDirect
|
|
( performDirect file key
|
|
, performIndirect file key)
|
|
|
|
performIndirect :: FilePath -> Key -> CommandPerform
|
|
performIndirect file key = do
|
|
liftIO $ removeFile file
|
|
|
|
-- git rm deletes empty directory without --cached
|
|
inRepo $ Git.Command.run [Params "rm --cached --force --quiet --", File file]
|
|
|
|
-- If the file was already committed, it is now staged for removal.
|
|
-- Commit that removal now, to avoid later confusing the
|
|
-- pre-commit hook, if this file is later added back to
|
|
-- git as a normal non-annexed file, to thinking that the
|
|
-- file has been unlocked and needs to be re-annexed.
|
|
(s, reap) <- inRepo $ LsFiles.staged [file]
|
|
unless (null s) $
|
|
inRepo $ Git.Command.run
|
|
[ Param "commit"
|
|
, Param "-q"
|
|
, Param "--no-verify"
|
|
, Param "-m", Param "content removed from git annex"
|
|
, Param "--", File file
|
|
]
|
|
void $ liftIO reap
|
|
|
|
next $ cleanupIndirect file key
|
|
|
|
cleanupIndirect :: FilePath -> Key -> CommandCleanup
|
|
cleanupIndirect file key = do
|
|
src <- calcRepo $ gitAnnexLocation key
|
|
ifM (Annex.getState Annex.fast)
|
|
( hardlinkfrom src
|
|
, copyfrom src
|
|
)
|
|
where
|
|
copyfrom src =
|
|
thawContent file `after` liftIO (copyFileExternal src file)
|
|
hardlinkfrom src =
|
|
#ifndef mingw32_HOST_OS
|
|
-- creating a hard link could fall; fall back to copying
|
|
ifM (liftIO $ catchBoolIO $ createLink src file >> return True)
|
|
( return True
|
|
, copyfrom src
|
|
)
|
|
#else
|
|
copyfrom src
|
|
#endif
|
|
|
|
performDirect :: FilePath -> Key -> CommandPerform
|
|
performDirect file key = do
|
|
-- --force is needed when the file is not committed
|
|
inRepo $ Git.Command.run [Params "rm --cached --force --quiet --", File file]
|
|
next $ cleanupDirect file key
|
|
|
|
{- The direct mode file is not touched during unannex, so the content
|
|
- is already where it needs to be, so this does not need to do anything
|
|
- except remove it from the associated file map (which also updates
|
|
- the location log if this was the last copy), and, if this was the last
|
|
- associated file, remove the inode cache. -}
|
|
cleanupDirect :: FilePath -> Key -> CommandCleanup
|
|
cleanupDirect file key = do
|
|
fs <- removeAssociatedFile key file
|
|
when (null fs) $
|
|
removeInodeCache key
|
|
return True
|