591e4b145f
This preserves the workaround for the old bug that caused NoUUID items to be stored in the log, prefixing log lines with " ". It's now handled implicitly, by using takeWhile1 (/= ' ') to get the uuid. There is a behavior change from the old parser, which split the value into words and then recombined it. That meant that "foo bar" and "foo\tbar" came out as "foo bar". That behavior was not documented, and seems surprising; it meant that after a git-annex describe here "foo bar", you wouldn't get that same string back out when git-annex displayed repo descriptions. Otoh, some other parsers relied on the old behavior, and the attoparsec rewrites had to deal with the issue themselves... For group.log, there are some edge cases around the user providing a group name with a leading or trailing space. The old parser would ignore such excess whitespace. The new parser does too, because the alternative is to refuse to parse something like " group1 group2 " due to excess whitespace, which would be even more confusing behavior. The only git-annex branch log file that is not converted to attoparsec and bytestring-builder now is transitions.log.
95 lines
2.6 KiB
Haskell
95 lines
2.6 KiB
Haskell
{- git-annex uuid-based logs
|
|
-
|
|
- This is used to store information about UUIDs in a way that can
|
|
- be union merged.
|
|
-
|
|
- A line of the log will look like: "UUID[ INFO[ timestamp=foo]]"
|
|
- The timestamp is last for backwards compatability reasons,
|
|
- and may not be present on old log lines.
|
|
-
|
|
- New uuid based logs instead use the form: "timestamp UUID INFO"
|
|
-
|
|
- Copyright 2011-2019 Joey Hess <id@joeyh.name>
|
|
-
|
|
- Licensed under the GNU GPL version 3 or higher.
|
|
-}
|
|
|
|
{-# LANGUAGE OverloadedStrings, TupleSections #-}
|
|
|
|
module Logs.UUIDBased (
|
|
Log,
|
|
LogEntry(..),
|
|
VectorClock,
|
|
currentVectorClock,
|
|
parseLog,
|
|
parseLogNew,
|
|
parseLogWithUUID,
|
|
buildLog,
|
|
buildLogNew,
|
|
changeLog,
|
|
addLog,
|
|
simpleMap,
|
|
) where
|
|
|
|
import qualified Data.Map as M
|
|
|
|
import Common
|
|
import Types.UUID
|
|
import Annex.VectorClock
|
|
import Logs.MapLog
|
|
import Logs.Line
|
|
|
|
import qualified Data.ByteString as S
|
|
import qualified Data.ByteString.Lazy as L
|
|
import qualified Data.Attoparsec.ByteString.Lazy as A
|
|
import qualified Data.Attoparsec.ByteString.Char8 as A8
|
|
import Data.ByteString.Builder
|
|
import qualified Data.DList as D
|
|
|
|
type Log v = MapLog UUID v
|
|
|
|
buildLog :: (v -> Builder) -> Log v -> Builder
|
|
buildLog builder = mconcat . map genline . M.toList
|
|
where
|
|
genline (u, LogEntry c@(VectorClock {}) v) =
|
|
buildUUID u <> sp <> builder v <> sp <>
|
|
byteString "timestamp=" <> buildVectorClock c <> nl
|
|
genline (u, LogEntry Unknown v) =
|
|
buildUUID u <> sp <> builder v <> nl
|
|
sp = charUtf8 ' '
|
|
nl = charUtf8 '\n'
|
|
|
|
parseLog :: A.Parser a -> L.ByteString -> Log a
|
|
parseLog = parseLogWithUUID . const
|
|
|
|
parseLogWithUUID :: (UUID -> A.Parser a) -> L.ByteString -> Log a
|
|
parseLogWithUUID parser = fromMaybe M.empty . A.maybeResult
|
|
. A.parse (logParser parser)
|
|
|
|
logParser :: (UUID -> A.Parser a) -> A.Parser (Log a)
|
|
logParser parser = M.fromListWith best <$> parseLogLines go
|
|
where
|
|
go = do
|
|
u <- toUUID <$> A8.takeWhile1 (/= ' ')
|
|
(dl, ts) <- accumval D.empty
|
|
v <- either fail return $ A.parseOnly (parser u <* A.endOfInput)
|
|
(S.intercalate " " $ D.toList dl)
|
|
return (u, LogEntry ts v)
|
|
accumval dl =
|
|
((dl,) <$> parsetimestamp)
|
|
<|> (A8.char ' ' *> (A8.takeWhile (/= ' ')) >>= accumval . D.snoc dl)
|
|
parsetimestamp =
|
|
(A8.string " timestamp=" *> vectorClockParser <* A.endOfInput)
|
|
<|> (const Unknown <$> A.endOfInput)
|
|
|
|
buildLogNew :: (v -> Builder) -> Log v -> Builder
|
|
buildLogNew = buildMapLog buildUUID
|
|
|
|
parseLogNew :: A.Parser v -> L.ByteString -> Log v
|
|
parseLogNew = parseMapLog (toUUID <$> A.takeByteString)
|
|
|
|
changeLog :: VectorClock -> UUID -> v -> Log v -> Log v
|
|
changeLog = changeMapLog
|
|
|
|
addLog :: UUID -> LogEntry v -> Log v -> Log v
|
|
addLog = addMapLog
|