436f107715
The goal is to be able to run CommandStart in the main thread when -J is used, rather than unncessarily passing it off to a worker thread, which incurs overhead that is signficant when the CommandStart is going to quickly decide to stop. To do that, the message it displays needs to be displayed in the worker thread, after the CommandStart has run. Also, the change will mean that CommandStart will no longer necessarily run with the same Annex state as CommandPerform. While its docs already said it should avoid modifying Annex state, I audited all the CommandStart code as part of the conversion. (Note that CommandSeek already sometimes runs with a different Annex state, and that has not been a source of any problems, so I am not too worried that this change will lead to breakage going forward.) The only modification of Annex state I found was it calling allowMessages in some Commands that default to noMessages. Dealt with that by adding a startCustomOutput and a startingUsualMessages. This lets a command start with noMessages and then select the output it wants for each CommandStart. One bit of breakage: onlyActionOn has been removed from commands that used it. The plan is that, since a StartMessage contains an ActionItem, when a Key can be extracted from that, the parallel job runner can run onlyActionOn' automatically. Then commands won't need to worry about this detail. Future work. Otherwise, this was a fairly straightforward process of making each CommandStart compile again. Hopefully other behavior changes were mostly avoided. In a few cases, a command had a CommandStart that called a CommandPerform that then called showStart multiple times. I have collapsed those down to a single start action. The main command to perhaps suffer from it is Command.Direct, which used to show a start for each file, and no longer does. Another minor behavior change is that some commands used showStart before, but had an associated file and a Key available, so were changed to ShowStart with an ActionItemAssociatedFile. That will not change the normal output or behavior, but --json output will now include the key. This should not break it for anyone using a real json parser.
99 lines
2.9 KiB
Haskell
99 lines
2.9 KiB
Haskell
{- git-annex command
|
|
-
|
|
- Copyright 2010-2019 Joey Hess <id@joeyh.name>
|
|
-
|
|
- Licensed under the GNU AGPL version 3 or higher.
|
|
-}
|
|
|
|
{-# LANGUAGE BangPatterns #-}
|
|
|
|
module Command.FromKey where
|
|
|
|
import Command
|
|
import qualified Annex.Queue
|
|
import Annex.Content
|
|
import Annex.WorkTree
|
|
import qualified Annex
|
|
import qualified Backend.URL
|
|
|
|
import Network.URI
|
|
|
|
cmd :: Command
|
|
cmd = notDirect $ notBareRepo $ withGlobalOptions [jsonOptions] $
|
|
command "fromkey" SectionPlumbing "adds a file using a specific key"
|
|
(paramRepeating (paramPair paramKey paramPath))
|
|
(seek <$$> optParser)
|
|
|
|
data FromKeyOptions = FromKeyOptions
|
|
{ keyFilePairs :: CmdParams
|
|
, batchOption :: BatchMode
|
|
}
|
|
|
|
optParser :: CmdParamsDesc -> Parser FromKeyOptions
|
|
optParser desc = FromKeyOptions
|
|
<$> cmdParams desc
|
|
<*> parseBatchOption
|
|
|
|
seek :: FromKeyOptions -> CommandSeek
|
|
seek o = case (batchOption o, keyFilePairs o) of
|
|
(Batch fmt, _) -> seekBatch fmt
|
|
-- older way of enabling batch input, does not support BatchNull
|
|
(NoBatch, []) -> seekBatch BatchLine
|
|
(NoBatch, ps) -> do
|
|
force <- Annex.getState Annex.force
|
|
withPairs (commandAction . start force) ps
|
|
|
|
seekBatch :: BatchFormat -> CommandSeek
|
|
seekBatch fmt = batchInput fmt parse commandAction
|
|
where
|
|
parse s =
|
|
let (keyname, file) = separate (== ' ') s
|
|
in if not (null keyname) && not (null file)
|
|
then Right $ go file (mkKey keyname)
|
|
else Left "Expected pairs of key and filename"
|
|
go file key = starting "fromkey" (mkActionItem (key, file)) $
|
|
perform key file
|
|
|
|
start :: Bool -> (String, FilePath) -> CommandStart
|
|
start force (keyname, file) = do
|
|
let key = mkKey keyname
|
|
unless force $ do
|
|
inbackend <- inAnnex key
|
|
unless inbackend $ giveup $
|
|
"key ("++ keyname ++") is not present in backend (use --force to override this sanity check)"
|
|
starting "fromkey" (mkActionItem (key, file)) $
|
|
perform key file
|
|
|
|
-- From user input to a Key.
|
|
-- User can input either a serialized key, or an url.
|
|
--
|
|
-- In some cases, an input can be parsed as both a key and as an uri.
|
|
-- For example, "WORM--a:a" parses as an uri. To disambiguate, check
|
|
-- the uri scheme, to see if it looks like the prefix of a key. This relies
|
|
-- on key backend names never containing a ':'.
|
|
mkKey :: String -> Key
|
|
mkKey s = case parseURI s of
|
|
Just u | not (isKeyPrefix (uriScheme u)) ->
|
|
Backend.URL.fromUrl s Nothing
|
|
_ -> case deserializeKey s of
|
|
Just k -> k
|
|
Nothing -> giveup $ "bad key/url " ++ s
|
|
|
|
perform :: Key -> FilePath -> CommandPerform
|
|
perform key file = lookupFileNotHidden file >>= \case
|
|
Nothing -> ifM (liftIO $ doesFileExist file)
|
|
( hasothercontent
|
|
, do
|
|
link <- calcRepo $ gitAnnexLink file key
|
|
liftIO $ createDirectoryIfMissing True (parentDir file)
|
|
liftIO $ createSymbolicLink link file
|
|
Annex.Queue.addCommand "add" [Param "--"] [file]
|
|
next $ return True
|
|
)
|
|
Just k
|
|
| k == key -> next $ return True
|
|
| otherwise -> hasothercontent
|
|
where
|
|
hasothercontent = do
|
|
warning $ file ++ " already exists with different content"
|
|
next $ return False
|