82a239675f
Check just before running update-index if the worktree file's content is still the same, don't update it when it's been modified. This narrows the race window a lot, from possibly minutes or hours, to seconds or less. (Use replaceFile so that the worktree update happens atomically, allowing the InodeCache of the new worktree file to itself be gathered w/o any other race.) This doesn't eliminate the race; it can still occur in the window before update-index runs. When annex.queue is large, a lot of files will be statted by the checks, and so the window may still be large enough to be a problem. When only a few files are being processed, the window is as small as it is in the race where a modification gets overwritten by git-annex when it updates the worktree. Or maybe as small as whatever race git checkout/pull/merge may have when the worktree gets modified during it. Still, I've kept a todo about this race. This commit was supported by the NSF-funded DataLad project.
56 lines
1.7 KiB
Haskell
56 lines
1.7 KiB
Haskell
{- git-annex file replacing
|
|
-
|
|
- Copyright 2013-2015 Joey Hess <id@joeyh.name>
|
|
-
|
|
- Licensed under the GNU GPL version 3 or higher.
|
|
-}
|
|
|
|
{-# LANGUAGE CPP #-}
|
|
|
|
module Annex.ReplaceFile where
|
|
|
|
import Annex.Common
|
|
import Annex.Perms
|
|
import Utility.Tmp.Dir
|
|
import Utility.Path.Max
|
|
|
|
{- Replaces a possibly already existing file with a new version,
|
|
- atomically, by running an action.
|
|
-
|
|
- The action is passed the name of temp file, in a temp directory,
|
|
- which it can write to, and once done the temp file is moved into place
|
|
- and anything else in the temp directory is deleted.
|
|
-
|
|
- The action can throw an exception, in which case the temp directory
|
|
- will be deleted, and the existing file will be preserved.
|
|
-
|
|
- Throws an IO exception when it was unable to replace the file.
|
|
-}
|
|
replaceFile :: FilePath -> (FilePath -> Annex a) -> Annex a
|
|
replaceFile file action = do
|
|
misctmpdir <- fromRepo gitAnnexTmpMiscDir
|
|
void $ createAnnexDirectory misctmpdir
|
|
#ifndef mingw32_HOST_OS
|
|
-- Use part of the filename as the template for the temp
|
|
-- directory. This does not need to be unique, but it
|
|
-- makes it more clear what this temp directory is for.
|
|
filemax <- liftIO $ fileNameLengthLimit misctmpdir
|
|
let basetmp = take (filemax `div` 2) (takeFileName file)
|
|
#else
|
|
-- Windows has limits on the whole path length, so keep
|
|
-- it short.
|
|
let basetmp = "t"
|
|
#endif
|
|
withTmpDirIn misctmpdir basetmp $ \tmpdir -> do
|
|
let tmpfile = tmpdir </> basetmp
|
|
r <- action tmpfile
|
|
liftIO $ replaceFileFrom tmpfile file
|
|
return r
|
|
|
|
replaceFileFrom :: FilePath -> FilePath -> IO ()
|
|
replaceFileFrom src dest = go `catchIO` fallback
|
|
where
|
|
go = moveFile src dest
|
|
fallback _ = do
|
|
createDirectoryIfMissing True $ parentDir dest
|
|
go
|