67fd06af76
(And a vpop command, which is still a bit buggy.) Still need to do vadd and vrm, though this also adds their documentation. Currently not very happy with the view log data serialization. I had to lose the TDFA regexps temporarily, so I can have Read/Show instances of View. I expect the view log format will change in some incompatable way later, probably adding last known refs for the parent branch to View or something like that. Anyway, it basically works, although it's a bit slow looking up the metadata. The actual git branch construction is about as fast as it can be using the current git plumbing. This commit was sponsored by Peter Hogg.
58 lines
1.7 KiB
Haskell
58 lines
1.7 KiB
Haskell
{- git hash-object interface
|
|
-
|
|
- Copyright 2011-2014 Joey Hess <joey@kitenet.net>
|
|
-
|
|
- Licensed under the GNU GPL version 3 or higher.
|
|
-}
|
|
|
|
module Git.HashObject where
|
|
|
|
import Common
|
|
import Git
|
|
import Git.Sha
|
|
import Git.Command
|
|
import Git.Types
|
|
import qualified Utility.CoProcess as CoProcess
|
|
import Utility.Tmp
|
|
|
|
type HashObjectHandle = CoProcess.CoProcessHandle
|
|
|
|
hashObjectStart :: Repo -> IO HashObjectHandle
|
|
hashObjectStart = CoProcess.rawMode <=< gitCoProcessStart True
|
|
[ Param "hash-object"
|
|
, Param "-w"
|
|
, Param "--stdin-paths"
|
|
, Param "--no-filters"
|
|
]
|
|
|
|
hashObjectStop :: HashObjectHandle -> IO ()
|
|
hashObjectStop = CoProcess.stop
|
|
|
|
{- Injects a file into git, returning the Sha of the object. -}
|
|
hashFile :: HashObjectHandle -> FilePath -> IO Sha
|
|
hashFile h file = CoProcess.query h send receive
|
|
where
|
|
send to = hPutStrLn to file
|
|
receive from = getSha "hash-object" $ hGetLine from
|
|
|
|
{- Injects a blob into git. Unfortunately, the current git-hash-object
|
|
- interface does not allow batch hashing without using temp files. -}
|
|
hashBlob :: HashObjectHandle -> String -> IO Sha
|
|
hashBlob h s = withTmpFile "hash" $ \tmp tmph -> do
|
|
hPutStr tmph s
|
|
hClose tmph
|
|
hashFile h tmp
|
|
|
|
{- Injects some content into git, returning its Sha.
|
|
-
|
|
- Avoids using a tmp file, but runs a new hash-object command each
|
|
- time called. -}
|
|
hashObject :: ObjectType -> String -> Repo -> IO Sha
|
|
hashObject objtype content = hashObject' objtype (flip hPutStr content)
|
|
|
|
hashObject' :: ObjectType -> (Handle -> IO ()) -> Repo -> IO Sha
|
|
hashObject' objtype writer repo = getSha subcmd $
|
|
pipeWriteRead (map Param params) (Just writer) repo
|
|
where
|
|
subcmd = "hash-object"
|
|
params = [subcmd, "-t", show objtype, "-w", "--stdin", "--no-filters"]
|