05989556a2
This adds a separate journal, which does not currently get committed to an index, but is planned to be committed to .git/annex/index-private. Changes that are regarding a UUID that is private will get written to this journal, and so will not be published into the git-annex branch. All log writing should have been made to indicate the UUID it's regarding, though I've not verified this yet. Currently, no UUIDs are treated as private yet, a way to configure that is needed. The implementation is careful to not add any additional IO work when privateUUIDsKnown is False. It will skip looking at the private journal at all. So this should be free, or nearly so, unless the feature is used. When it is used, all branch reads will be about twice as expensive. It is very lucky -- or very prudent design -- that Annex.Branch.change and maybeChange are the only ways to change a file on the branch, and Annex.Branch.set is only internal use. That let Annex.Branch.get always yield any private information that has been recorded, without the risk that Annex.Branch.set might be called, with a non-private UUID, and end up leaking the private information into the git-annex branch. And, this relies on the way git-annex union merges the git-annex branch. When reading a file, there can be a public and a private version, and they are just concacenated together. That will be handled the same as if there were two diverged git-annex branches that got union merged.
84 lines
3 KiB
Haskell
84 lines
3 KiB
Haskell
{- unparsed preferred content expressions
|
|
-
|
|
- Copyright 2012-2019 Joey Hess <id@joeyh.name>
|
|
-
|
|
- Licensed under the GNU AGPL version 3 or higher.
|
|
-}
|
|
|
|
module Logs.PreferredContent.Raw where
|
|
|
|
import Annex.Common
|
|
import qualified Annex.Branch
|
|
import qualified Annex
|
|
import Logs
|
|
import Logs.UUIDBased
|
|
import Logs.MapLog
|
|
import Types.StandardGroups
|
|
import Types.Group
|
|
|
|
import qualified Data.Map as M
|
|
import qualified Data.ByteString.Lazy as L
|
|
import qualified Data.Attoparsec.ByteString.Lazy as A
|
|
import Data.ByteString.Builder
|
|
|
|
{- Changes the preferred content configuration of a remote. -}
|
|
preferredContentSet :: UUID -> PreferredContentExpression -> Annex ()
|
|
preferredContentSet = setLog preferredContentLog
|
|
|
|
requiredContentSet :: UUID -> PreferredContentExpression -> Annex ()
|
|
requiredContentSet = setLog requiredContentLog
|
|
|
|
setLog :: RawFilePath -> UUID -> PreferredContentExpression -> Annex ()
|
|
setLog logfile uuid@(UUID _) val = do
|
|
c <- currentVectorClock
|
|
Annex.Branch.change (Annex.Branch.RegardingUUID [uuid]) logfile $
|
|
buildLogOld buildPreferredContentExpression
|
|
. changeLog c uuid val
|
|
. parseLogOld parsePreferredContentExpression
|
|
Annex.changeState $ \s -> s
|
|
{ Annex.preferredcontentmap = Nothing
|
|
, Annex.requiredcontentmap = Nothing
|
|
}
|
|
setLog _ NoUUID _ = error "unknown UUID; cannot modify"
|
|
|
|
{- Changes the preferred content configuration of a group. -}
|
|
groupPreferredContentSet :: Group -> PreferredContentExpression -> Annex ()
|
|
groupPreferredContentSet g val = do
|
|
c <- currentVectorClock
|
|
Annex.Branch.change
|
|
(Annex.Branch.RegardingUUID [])
|
|
groupPreferredContentLog $
|
|
buildGroupPreferredContent
|
|
. changeMapLog c g val
|
|
. parseGroupPreferredContent
|
|
Annex.changeState $ \s -> s { Annex.preferredcontentmap = Nothing }
|
|
|
|
parseGroupPreferredContent :: L.ByteString -> MapLog Group String
|
|
parseGroupPreferredContent = parseMapLog parsegroup parsestring
|
|
where
|
|
parsegroup = Group <$> A.takeByteString
|
|
parsestring = decodeBS <$> A.takeByteString
|
|
|
|
buildGroupPreferredContent :: MapLog Group PreferredContentExpression -> Builder
|
|
buildGroupPreferredContent = buildMapLog buildgroup buildexpr
|
|
where
|
|
buildgroup (Group g) = byteString g
|
|
buildexpr = byteString . encodeBS
|
|
|
|
parsePreferredContentExpression :: A.Parser PreferredContentExpression
|
|
parsePreferredContentExpression = decodeBS <$> A.takeByteString
|
|
|
|
buildPreferredContentExpression :: PreferredContentExpression -> Builder
|
|
buildPreferredContentExpression = byteString . encodeBS
|
|
|
|
preferredContentMapRaw :: Annex (M.Map UUID PreferredContentExpression)
|
|
preferredContentMapRaw = simpleMap . parseLogOld parsePreferredContentExpression
|
|
<$> Annex.Branch.get preferredContentLog
|
|
|
|
requiredContentMapRaw :: Annex (M.Map UUID PreferredContentExpression)
|
|
requiredContentMapRaw = simpleMap . parseLogOld parsePreferredContentExpression
|
|
<$> Annex.Branch.get requiredContentLog
|
|
|
|
groupPreferredContentMapRaw :: Annex (M.Map Group PreferredContentExpression)
|
|
groupPreferredContentMapRaw = simpleMap . parseGroupPreferredContent
|
|
<$> Annex.Branch.get groupPreferredContentLog
|