1acdd18ea8
* Deal with clock skew, both forwards and backwards, when logging information to the git-annex branch. * GIT_ANNEX_VECTOR_CLOCK can now be set to a fixed value (eg 1) rather than needing to be advanced each time a new change is made. * Misuse of GIT_ANNEX_VECTOR_CLOCK will no longer confuse git-annex. When changing a file in the git-annex branch, the vector clock to use is now determined by first looking at the current time (or GIT_ANNEX_VECTOR_CLOCK when set), and comparing it to the newest vector clock already in use in that file. If a newer time stamp was already in use, advance it forward by a second instead. When the clock is set to a time in the past, this avoids logging with an old timestamp, which would risk that log line later being ignored in favor of "newer" line that is really not newer. When a log entry has been made with a clock that was set far ahead in the future, this avoids newer information being logged with an older timestamp and so being ignored in favor of that future-timestamped information. Once all clocks get fixed, this will result in the vector clocks being incremented, until finally enough time has passed that time gets back ahead of the vector clock value, and then it will return to usual operation. (This latter situation is not ideal, but it seems the best that can be done. The issue with it is, since all writers will be incrementing the last vector clock they saw, there's no way to tell when one writer made a write significantly later in time than another, so the earlier write might arbitrarily be picked when merging. This problem is why git-annex uses timestamps in the first place, rather than pure vector clocks.) Advancing forward by 1 second is somewhat arbitrary. setDead advances a timestamp by just 1 picosecond, and the vector clock could too. But then it would interfere with setDead, which wants to be overrulled by any change. So it could use 2 picoseconds or something, but that seems weird. It could just as well advance it forward by a minute or whatever, but then it would be harder for real time to catch up with the vector clock when forward clock slew had happened. A complication is that many log files contain several different peices of information, and it may be best to only use vector clocks for the same peice of information. For example, a key's location log file contains InfoPresent/InfoMissing for each UUID, and it only looks at the vector clocks for the UUID that is being changed, and not other UUIDs. Although exactly where the dividing line is can be hard to determine. Consider metadata logs, where a field "tag" can have multiple values set at different times. Should it advance forward past the last tag? Probably. What about when a different field is set, should it look at the clocks of other fields? Perhaps not, but currently it does, and this does not seems like it will cause any problems. Another one I'm not entirely sure about is the export log, which is keyed by (fromuuid, touuid). So if multiple repos are exporting to the same remote, different vector clocks can be used for that remote. It looks like that's probably ok, because it does not try to determine what order things occurred when there was an export conflict. Sponsored-by: Jochen Bartl on Patreon
98 lines
2.7 KiB
Haskell
98 lines
2.7 KiB
Haskell
{- git-annex uuid-based logs
|
|
-
|
|
- This is used to store information about UUIDs in a way that can
|
|
- be union merged.
|
|
-
|
|
- The old format looks like: "UUID[ INFO[ timestamp=foo]]"
|
|
- The timestamp is last for backwards compatability reasons,
|
|
- and may not be present on very old log lines.
|
|
-
|
|
- New uuid based logs instead use the form: "timestamp UUID INFO"
|
|
-
|
|
- Copyright 2011-2019 Joey Hess <id@joeyh.name>
|
|
-
|
|
- Licensed under the GNU AGPL version 3 or higher.
|
|
-}
|
|
|
|
{-# LANGUAGE OverloadedStrings, TupleSections #-}
|
|
|
|
module Logs.UUIDBased (
|
|
Log,
|
|
LogEntry(..),
|
|
VectorClock,
|
|
currentVectorClock,
|
|
parseLogOld,
|
|
parseLogNew,
|
|
parseLogOldWithUUID,
|
|
buildLogOld,
|
|
buildLogNew,
|
|
changeLog,
|
|
addLog,
|
|
simpleMap,
|
|
) where
|
|
|
|
import qualified Data.Map as M
|
|
|
|
import Common
|
|
import Types.UUID
|
|
import Annex.VectorClock
|
|
import Logs.MapLog
|
|
import Logs.Line
|
|
|
|
import qualified Data.ByteString as S
|
|
import qualified Data.ByteString.Lazy as L
|
|
import qualified Data.Attoparsec.ByteString as A
|
|
import qualified Data.Attoparsec.ByteString.Lazy as AL
|
|
import qualified Data.Attoparsec.ByteString.Char8 as A8
|
|
import Data.ByteString.Builder
|
|
import qualified Data.DList as D
|
|
|
|
type Log v = MapLog UUID v
|
|
|
|
buildLogOld :: (v -> Builder) -> Log v -> Builder
|
|
buildLogOld builder = mconcat . map genline . M.toList
|
|
where
|
|
genline (u, LogEntry c@(VectorClock {}) v) =
|
|
buildUUID u <> sp <> builder v <> sp
|
|
<> byteString "timestamp="
|
|
<> buildVectorClock c
|
|
<> nl
|
|
genline (u, LogEntry Unknown v) =
|
|
buildUUID u <> sp <> builder v <> nl
|
|
sp = charUtf8 ' '
|
|
nl = charUtf8 '\n'
|
|
|
|
parseLogOld :: A.Parser a -> L.ByteString -> Log a
|
|
parseLogOld = parseLogOldWithUUID . const
|
|
|
|
parseLogOldWithUUID :: (UUID -> A.Parser a) -> L.ByteString -> Log a
|
|
parseLogOldWithUUID parser = fromMaybe M.empty . AL.maybeResult
|
|
. AL.parse (logParserOld parser)
|
|
|
|
logParserOld :: (UUID -> A.Parser a) -> A.Parser (Log a)
|
|
logParserOld parser = M.fromListWith best <$> parseLogLines go
|
|
where
|
|
go = do
|
|
u <- toUUID <$> A8.takeWhile1 (/= ' ')
|
|
(dl, ts) <- accumval D.empty
|
|
v <- either fail return $ A.parseOnly (parser u <* A.endOfInput)
|
|
(S.intercalate " " $ D.toList dl)
|
|
return (u, LogEntry ts v)
|
|
accumval dl =
|
|
((dl,) <$> parsetimestamp)
|
|
<|> (A8.char ' ' *> (A8.takeWhile (/= ' ')) >>= accumval . D.snoc dl)
|
|
parsetimestamp =
|
|
(A8.string " timestamp=" *> vectorClockParser <* A.endOfInput)
|
|
<|> (const Unknown <$> A.endOfInput)
|
|
|
|
buildLogNew :: (v -> Builder) -> Log v -> Builder
|
|
buildLogNew = buildMapLog buildUUID
|
|
|
|
parseLogNew :: A.Parser v -> L.ByteString -> Log v
|
|
parseLogNew = parseMapLog (toUUID <$> A.takeByteString)
|
|
|
|
changeLog :: CandidateVectorClock -> UUID -> v -> Log v -> Log v
|
|
changeLog = changeMapLog
|
|
|
|
addLog :: UUID -> LogEntry v -> Log v -> Log v
|
|
addLog = addMapLog
|