38d691a10f
Running git-annex linux builds in termux seems to work well enough that the only reason to keep the Android app would be to support Android 4-5, which the old Android app supported, and which I don't know if the termux method works on (although I see no reason why it would not). According to [1], Android 4-5 remains on around 29% of devices, down from 51% one year ago. [1] https://www.statista.com/statistics/271774/share-of-android-platforms-on-mobile-devices-with-android-os/ This is a rather large commit, but mostly very straightfoward removal of android ifdefs and patches and associated cruft. Also, removed support for building with very old ghc < 8.0.1, and with yesod < 1.4.3, and without concurrent-output, which were only being used by the cross build. Some documentation specific to the Android app (screenshots etc) needs to be updated still. This commit was sponsored by Brett Eisenberg on Patreon.
50 lines
1.6 KiB
Haskell
50 lines
1.6 KiB
Haskell
{- Adjusting the environment while running git commands.
|
|
-
|
|
- Copyright 2014-2016 Joey Hess <id@joeyh.name>
|
|
-
|
|
- Licensed under the GNU GPL version 3 or higher.
|
|
-}
|
|
|
|
module Git.Env where
|
|
|
|
import Common
|
|
import Git
|
|
import Git.Types
|
|
import Utility.Env
|
|
|
|
{- Adjusts the gitEnv of a Repo. Copies the system environment if the repo
|
|
- does not have any gitEnv yet. -}
|
|
adjustGitEnv :: Repo -> ([(String, String)] -> [(String, String)]) -> IO Repo
|
|
adjustGitEnv g adj = do
|
|
e <- maybe getEnvironment return (gitEnv g)
|
|
let e' = adj e
|
|
return $ g { gitEnv = Just e' }
|
|
where
|
|
|
|
addGitEnv :: Repo -> String -> String -> IO Repo
|
|
addGitEnv g var val = adjustGitEnv g (addEntry var val)
|
|
|
|
{- Environment variables to use when running a command.
|
|
- Includes GIT_DIR pointing at the repo, and GIT_WORK_TREE when the repo
|
|
- is not bare. Also includes anything added to the Repo's gitEnv,
|
|
- and a copy of the rest of the system environment. -}
|
|
propGitEnv :: Repo -> IO [(String, String)]
|
|
propGitEnv g = do
|
|
g' <- addGitEnv g "GIT_DIR" (localGitDir g)
|
|
g'' <- maybe (pure g') (addGitEnv g' "GIT_WORK_TREE") (repoWorkTree g)
|
|
return $ fromMaybe [] (gitEnv g'')
|
|
|
|
{- Use with any action that makes a commit to set metadata. -}
|
|
commitWithMetaData :: CommitMetaData -> CommitMetaData -> (Repo -> IO a) -> Repo -> IO a
|
|
commitWithMetaData authormetadata committermetadata a g =
|
|
a =<< adjustGitEnv g adj
|
|
where
|
|
adj = mkadj "AUTHOR" authormetadata
|
|
. mkadj "COMMITTER" committermetadata
|
|
mkadj p md = go "NAME" commitName
|
|
. go "EMAIL" commitEmail
|
|
. go "DATE" commitDate
|
|
where
|
|
go s getv = case getv md of
|
|
Nothing -> id
|
|
Just v -> addEntry ("GIT_" ++ p ++ "_" ++ s) v
|