make CommandStart return a StartMessage

The goal is to be able to run CommandStart in the main thread when -J is
used, rather than unncessarily passing it off to a worker thread, which
incurs overhead that is signficant when the CommandStart is going to
quickly decide to stop.

To do that, the message it displays needs to be displayed in the worker
thread, after the CommandStart has run.

Also, the change will mean that CommandStart will no longer necessarily
run with the same Annex state as CommandPerform. While its docs already
said it should avoid modifying Annex state, I audited all the
CommandStart code as part of the conversion. (Note that CommandSeek
already sometimes runs with a different Annex state, and that has not been
a source of any problems, so I am not too worried that this change will
lead to breakage going forward.)

The only modification of Annex state I found was it calling
allowMessages in some Commands that default to noMessages. Dealt with
that by adding a startCustomOutput and a startingUsualMessages.
This lets a command start with noMessages and then select the output it
wants for each CommandStart.

One bit of breakage: onlyActionOn has been removed from commands that used it.
The plan is that, since a StartMessage contains an ActionItem,
when a Key can be extracted from that, the parallel job runner can
run onlyActionOn' automatically. Then commands won't need to worry about
this detail. Future work.

Otherwise, this was a fairly straightforward process of making each
CommandStart compile again. Hopefully other behavior changes were mostly
avoided.

In a few cases, a command had a CommandStart that called a CommandPerform
that then called showStart multiple times. I have collapsed those
down to a single start action. The main command to perhaps suffer from it
is Command.Direct, which used to show a start for each file, and no
longer does.

Another minor behavior change is that some commands used showStart
before, but had an associated file and a Key available, so were changed
to ShowStart with an ActionItemAssociatedFile. That will not change the
normal output or behavior, but --json output will now include the key.
This should not break it for anyone using a real json parser.

Types/ActionItem.hs

@@ -13,21 +13,34 @@ import Key
 import Types.Transfer
 import Git.FilePath
 
+import Data.Maybe
+
 data ActionItem 
 	= ActionItemAssociatedFile AssociatedFile Key
 	| ActionItemKey Key
 	| ActionItemBranchFilePath BranchFilePath Key
 	| ActionItemFailedTransfer Transfer TransferInfo
+	| ActionItemWorkTreeFile FilePath
+	| ActionItemOther (Maybe String)
 
 class MkActionItem t where
 	mkActionItem :: t -> ActionItem
 
+instance MkActionItem ActionItem where
+	mkActionItem = id
+
 instance MkActionItem (AssociatedFile, Key) where
 	mkActionItem = uncurry ActionItemAssociatedFile
 
 instance MkActionItem (Key, AssociatedFile) where
 	mkActionItem = uncurry $ flip ActionItemAssociatedFile
 
+instance MkActionItem (Key, FilePath) where
+	mkActionItem (key, file) = ActionItemAssociatedFile (AssociatedFile (Just file)) key
+
+instance MkActionItem (FilePath, Key) where
+	mkActionItem (file, key) = mkActionItem (key, file)
+
 instance MkActionItem Key where
 	mkActionItem = ActionItemKey
 
@@ -39,20 +52,26 @@ instance MkActionItem (Transfer, TransferInfo) where
 
 actionItemDesc :: ActionItem -> String
 actionItemDesc (ActionItemAssociatedFile (AssociatedFile (Just f)) _) = f
-actionItemDesc (ActionItemAssociatedFile (AssociatedFile Nothing) k) = serializeKey k
+actionItemDesc (ActionItemAssociatedFile (AssociatedFile Nothing) k) = 
+	serializeKey k
 actionItemDesc (ActionItemKey k) = serializeKey k
 actionItemDesc (ActionItemBranchFilePath bfp _) = descBranchFilePath bfp
 actionItemDesc (ActionItemFailedTransfer t i) = actionItemDesc $
 	ActionItemAssociatedFile (associatedFile i) (transferKey t)
+actionItemDesc (ActionItemWorkTreeFile f) = f
+actionItemDesc (ActionItemOther s) = fromMaybe "" s
 
-actionItemKey :: ActionItem -> Key
-actionItemKey (ActionItemAssociatedFile _ k) = k
-actionItemKey (ActionItemKey k) = k
-actionItemKey (ActionItemBranchFilePath _ k) = k
-actionItemKey (ActionItemFailedTransfer t _) = transferKey t
+actionItemKey :: ActionItem -> Maybe Key
+actionItemKey (ActionItemAssociatedFile _ k) = Just k
+actionItemKey (ActionItemKey k) = Just k
+actionItemKey (ActionItemBranchFilePath _ k) = Just k
+actionItemKey (ActionItemFailedTransfer t _) = Just (transferKey t)
+actionItemKey (ActionItemWorkTreeFile _) = Nothing
+actionItemKey (ActionItemOther _) = Nothing
 
 actionItemWorkTreeFile :: ActionItem -> Maybe FilePath
 actionItemWorkTreeFile (ActionItemAssociatedFile (AssociatedFile af) _) = af
+actionItemWorkTreeFile (ActionItemWorkTreeFile f) = Just f
 actionItemWorkTreeFile _ = Nothing
 
 actionItemTransferDirection :: ActionItem -> Maybe Direction

Types/Command.hs

@@ -1,6 +1,6 @@
 {- git-annex command data types
  -
- - Copyright 2010-2016 Joey Hess <id@joeyh.name>
+ - Copyright 2010-2019 Joey Hess <id@joeyh.name>
  -
  - Licensed under the GNU AGPL version 3 or higher.
  -}
@@ -12,6 +12,7 @@ import Options.Applicative.Types (Parser)
 
 import Types
 import Types.DeferredParse
+import Types.ActionItem
 
 {- A command runs in these stages.
  -
@@ -25,11 +26,11 @@ data CommandCheck = CommandCheck { idCheck :: Int, runCheck :: Annex () }
  -    the repo to find things to act on (ie, new files to add), and
  -    runs commandAction to handle all necessary actions. -}
 type CommandSeek = Annex ()
-{- d. The start stage is run before anything is printed about the
- -    command, is passed some input, and can early abort it
- -    if nothing needs to be done. It should run quickly and
- -    should not modify Annex state. -}
-type CommandStart = Annex (Maybe CommandPerform)
+{- d. The start stage is run before anything is output, is passed some
+ -    value from the seek stage, and can check if anything needs to be
+ -    done, and early abort if not. It should run quickly and should
+ -    not modify Annex state or output anything. -}
+type CommandStart = Annex (Maybe (StartMessage, CommandPerform))
 {- e. The perform stage is run after a message is printed about the command
  -    being run, and it should be where the bulk of the work happens. -}
 type CommandPerform = Annex (Maybe CommandCleanup)
@@ -37,6 +38,18 @@ type CommandPerform = Annex (Maybe CommandCleanup)
  -    returns the overall success/fail of the command. -}
 type CommandCleanup = Annex Bool
 
+{- Message that is displayed when starting to perform an action on
+ - something. The String is typically the name of the command or action
+ - being performed.
+ -
+ - CustomOutput prevents any start, end, or other implicit messages from
+ - being displayed, letting a command output its own custom format.
+ -}
+data StartMessage
+	= StartMessage String ActionItem
+	| StartUsualMessages String ActionItem
+	| CustomOutput
+
 {- A command is defined by specifying these things. -}
 data Command = Command
 	{ cmdcheck :: [CommandCheck] -- check stage